French whois

French whois

mIRC snippet ce afiseaza informatiile de whois in limba franceza

Postat de Copyright Categorie Review user Vizualizari Data
BLKoldSUN necunoscut activity Cod testat 394 2023-12-04 19:19:27 

alias whois {
  ;whois the selected user
  whois $$1 $$1
}

raw 311:*:{
  echo -a -
  echo -at $2 est $3 $+ @ $+ $4 $5 $replace($6,:,) $7-
  halt
}

raw 319:*:{
  ; storing all channels
  set %chan $replace($3,:,) $4-
  var %a 0
  ; %b is the number of channels
  var %b $gettok(%chan,0,32)
  while (%a < %b) {
    inc %a
    ; if a channel starts by "@#" so the user is operator.
    if ($left($gettok(%chan,%a,32),2) == @#) {
      var %chanOperator %chanOperator $gettok(%chan,%a,32)
    }
    ; if a channel starts by "+#" so the user is voiced.
    elseif ($left($gettok(%chan,%a,32),2) == +#) {
      var %chanVoice %chanVoice $gettok(%chan,%a,32)
    }
    ; other type of channels. (half operator, simple user, owner, etc...)
    else {
      var %chanUser %chanUser $gettok(%chan,%a,32)
    }
  }
  ; displaying filtered channels.
  if (%chanUser) {
    echo -at $2 est simple utilisateur sur %chanUser
  }
  if (%chanVoice) {
    echo -at $2 est voice sur %chanVoice
  }
  if (%chanOperator) {
    echo -at $2 est opérateur sur %chanOperator
  }
  unset %chan
  halt
}

raw 338:*:{
  echo -at $2 a pour host local et IP: $3 [[ $+ $4 $+ ]]
  halt
}

raw 312:*:{
  echo -at $2 est connecté sur le serveur $3-
  halt
}

raw 330:*:{
  echo -at $2 est authentifié sur le compte $3
  halt
}

raw 320:*:{
  echo -at $2 est connecté via la connexion sécurisée (SSL)
  halt
}

raw 313:*:{
  echo -at $2 est un opérateur IRC
  halt
}

raw 317:*:{
  ; converting signon and idle into hours, mins, secs format
  if ($3 > 3600) {
    var %idleTime $replace($duration($3,3),:,$chr(32))
    var %idleTime $gettok(%idleTime,1,32) $+ hrs $gettok(%idleTime,2,32) $+ mins et $gettok(%idleTime,3,32) $+ secs
  }
  elseif ($3 < 3600) {
    var %idleTime $replace($duration($3), , et )
  }
  var %signonTime $asctime($4,dd/mm/yy HH:nn:ss)
  echo -at $2 ne parle pas depuis %idleTime
  echo -at $2 est connecté depuis le %signonTime
  halt
}

raw 318:*:{
  echo -at $2 Fin du /WHOIS
  echo -a -
  halt
}

French whois