Proxy check

mIRC Snippet - Proxy check - verifica daca ip-ul de conectare se afla in dns blacklist. Fiind un cod vechi, este posibil sa nu mai functioneze, dar se poate refae usor.

Postat de	Copyright	Categorie	Review user	Vizualizari	Data
BLKoldSUN	necunoscut	protections	Cod netestat	338	2023-12-17 08:35:16

alias ProxyCheck { 
  if ($1 == $null) { 
    echo 4* Missing parameters: /proxycheck <ip> or to check your own ip /proxycheck localhost 
  }
  elseif ($1 == localhost) { 
    echo -a 3* Checking your ip address, Please wait...
    proxycheck:process $ProxyCheck:RevIP($ip)
  }
  elseif ($longIP($1)) {
    echo -a 3* Checking ip address, Please wait...
    proxycheck:Process $ProxyCheck:RevIP($1)
  }
}
alias -l ProxyCheck:Revip {
  tokenize 46 $1 
  return $+($4, ., $3, ., $2, ., $1)
}
alias -l ProxyCheck:BL {
  return $&
    .dronebl $&
    .proxybl $&
    .tor.dnsbl.sectoor $&
    .tor.dan.me.uk $&
    .dnsbl.njabl.org $&
    .rbl.efnet.org $&
    .virbl.dnsbl.bit.nl $&
    .dnsbl.ahbl.org $&
    .rbl.faynticrbl.org $&
    .dnsbl.ipocalypse.net $&
    .dnsbl.rizon.net $&
    .dnsbl.swiftbl.org
}
alias -l ProxyCheck:Process {
  var %ip = $1
  var %x = 1
  tokenize 32 $ProxyCheck:BL
  set -e $+(%,ProxyCheck:,%ip) $0
  while ($(,$ $+ %x)) {
    .dns %ip $+ $v1
    inc %x
  }
}
on *:DNS:{

  var %ip = $gettok($address,1-4,46)
  var %zone = $gettok($address,5-,46)

  if (%zone && $($+(%,ProxyCheck:,%ip),2)) {
    $iif($v1 == 1,unset,dec) $+(%,ProxyCheck:,%ip)
    echo $iif($iaddress,3,4) -a * The IP $ProxyCheck:RevIP(%ip) has $iif(!$iaddress,not) been found in BL zone %zone
    halt
  }
}